This article will give a simple example of how to move all the files from a specific Google Drive folder to the Trash using the G4GGDRV addon for GreenTools for Google Apps (G4G).

This is really done in two steps:

1. List all the files in a folder
2. Read through that list and move each file to the trash

This example will use the ILE functions (#g4gdrv_listFiles() and #g4gdrv_trashFile()) but the commands (G4GLSTFIL and G4GTRASH) can also be used. 

Specific documentation for these commands and ILE functions can be found in the G4G Documentation.

The source for the application is as follows:

     H DFTACTGRP(*NO) ACTGRP('G4G') BNDDIR('G4G')
      ****************************************************************
      /copy qcopysrc,p.g4gdrv
      ****************************************************************
     D id              S            256
     D errorMsg        S            256
     D rc              S             10i 0
     D fileID          S            128
      ****************************************************************
       id = 'bvstone@gmail.com';

       #g4gdrv_setValue('id':id);
       #g4gdrv_setValue('folder_name':'/test folder/subfolder 1');
       rc = #g4gdrv_listFiles(errorMsg);

       if (rc < 0);
         //handle error
       endif;

       if (rc > 0);
         exec sql
           declare C1 cursor for
           select GGDFILEID from G4GDRVPF
             where lower(GGDID) = :id and
                   lower(GGDMIME) <> 'application/vnd.google-apps.folder';

         exec sql open C1;

         exec sql fetch from C1
           into :fileID;

         dow (SQLCOD = 0);
           #g4gdrv_setValue('id':id);
           #g4gdrv_setValue('file_id':fileID);
           rc = #g4gdrv_trashFile(errorMsg);

           if (rc < 0);
             //handle error
           endif;

           exec sql fetch from C1
             into :fileID;
         enddo;

         exec sql
           close C1;

       endif;

       *INLR = *ON;

The first step is to use the #g4gdrv_listFiles() function to list all the files in a specific folder in our Google Drive.  All of the entries in a specific folder will be written to the file G4GDRVPF.

The G4GDRVPF file is keyed by Google ID and that is why in the next step when we run an SQL statement to select the records we make sure to only select records for our specific ID.  That is because if someone else is running a command their data will be in this file as well, and you don't want to accidentally trash their files!

We also select anything without a mime type of "application/vnd.google-apps.folder".  This is the mime type for a folder.  Most of the mime types used by Google Drive can be found here.

For each record we process we will simply call the #g4gdrv_trashFile() function and the file will be moved to the trash.

Here's an snapshot of a my Google Drive folder before calling this program:

Now, after calling this program, all the files (but not the "samples" folder) will be moved to trash:

So as you can see, using the functions available in the Google Drive Addon for G4G, there are many things you can do to upload, download and keep your Google Drive folders organized right from your IBM i using simple commands and RPG, or any ILE language!