Previously we discussed how to send an email when a job enters MSGW using JOBWATCH and MAILTOOL.

This article will expand on that and also send a message to a private Slack channel as a "bot" so that we will receive a notification on any device (like an android or iPhone) that has the Slack app installed.  The software we will need will be Job Watch (JOBWATCH) and GreenTools for Slack (G4SLK).

First we use the Job Watch Configuration (JOBWATCHCF) command to set up a call to a program when a job enters MSGW.  The command in this case looks like this:

CALL PGM(SLACKMSGW) PARM('&J' '&S' '&U' '&N' '&F' '&E')

This will cause JOBWATCH to call the program SLACKMSGW passing in the parameters Job, Job Status, User, Job Number, Function, and Error Text from the job log.

A list of replacement variables and their data sizes can be seen here in the documentation.

In my case I wanted to make sure the messages only came to me.  So I created a private channel in my Slack team named "alerts" that I will use to send alerts from my IBM i to.

Our RPG program that will send the Slack message is as follows:

     H DFTACTGRP(*NO) BNDDIR('BVSTOOLS')
      ****************************************************************
      * Prototypes                                                   *
      ****************************************************************
      /COPY QCOPYSRC,P.G4SLKCH
      ****************************************************************
     D MsgTS           S            256    INZ
     D ErrMsg          S            256    INZ
     D rc              S             10i 0
     D CRLF            S              2    INZ(X'0D25')
     D Message         S          32000
      ****************************************************************
     C     *ENTRY        PLIST
     C                   PARM                    WPJob            10
     C                   PARM                    WPJobStatus       4
     C                   PARM                    WPUser           10
     C                   PARM                    WPJobNbr          6
     C                   PARM                    WPFunction       10
     C                   PARM                    WPErrorText    4096
      /free
       EXSR $Slack;

       *INLR = *ON;
       //***************************************************************
       //* Send a Message to Slack
       //***************************************************************
       begsr $Slack;

         Message = 'JOB: ' + %trim(WPJob) + CRLF +
                   'JOB NUMBER: ' + %trim(WPJobNbr) + CRLF +
                   'STATUS: ' + %trim(WPJobStatus) + CRLF +
                   'FUNCTION: ' + %trim(WPFunction) + CRLF +
                   'MESSAGE: ' + CRLF + %trim(WPErrorText);

         rc = #g4slkch_setValue('id':'bvstools');
         rc = #g4slkch_setValue('team':'bvstools');
         rc = #g4slkch_setValue('channel':'alerts');
         rc = #g4slkch_setValue('as_who':'*BOT');
         rc = #g4slkch_setValue('user_name':'JobWatch');
         rc = #g4slkch_setValue('message':Message);
         msgTS = #g4slkch_sendMessage(errMsg);

       endsr;
      /end-free

All we need to do is build the message we want to send, set the values of our id, team and channel.  Also, in this case I'm sending the message as a "bot" with the name of "JobWatch" so that when my phone dings with the alert I will know what the issue most likely is before even having to look at the message.

Now, not only will the online Slack application show the message in the "alerts" channel:

But also my phone will also show the message:

Pretty neat!